integration-testing-conventions.gradle.kts

plugins {
    id("testing-conventions")
}

sourceSets {
    create("intTest") {
        compileClasspath += sourceSets.main.get().output
        runtimeClasspath += sourceSets.main.get().output
    }
}

val intTestImplementation by configurations.getting {
    extendsFrom(configurations.implementation.get())
}
val intTestRuntimeOnly by configurations.getting

configurations["intTestRuntimeOnly"].extendsFrom(configurations.runtimeOnly.get())

dependencies {
    intTestImplementation("org.springframework.boot:spring-boot-starter-test") {
        exclude(module = "hamcrest") // require developers to use KoTest
        exclude(module = "org.assertj") // require developers to use KoTest
    }
    intTestImplementation("io.kotest:kotest-runner-junit5:5.8.1")
}

val integrationTest = task<Test>("integrationTest") {
    description = "Runs integration tests."
    group = "verification"

    testClassesDirs = sourceSets["intTest"].output.classesDirs
    classpath = sourceSets["intTest"].runtimeClasspath
    shouldRunAfter("test")

    useJUnitPlatform()

    testLogging {
        showStandardStreams = true
    }
}

tasks.check { dependsOn(integrationTest) }