build.gradle

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'findbugs'
apply plugin: 'pmd'
apply plugin: 'checkstyle'
apply plugin: 'project-report'
apply plugin: 'maven'
apply plugin: 'build-dashboard'
apply plugin: 'signing'
buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'org.danilopianini:smartrrr:0.0.0'
    }
}
apply plugin: 'org.danilopianini.smartrrr'

sourceCompatibility = 1.8
targetCompatibility = 1.8

task wrapper(type: Wrapper) { gradleVersion = gradleVersionToUse }

// General configuration

jar {
    manifest {
        attributes 'Implementation-Title': artifactId, 'Implementation-Version': version
    }
}

repositories { mavenCentral() }

test { testLogging { exceptionFormat = 'full' } }

configurations {
    doc { transitive false }
    compile { exclude module: 'org.eclipse.xtext.dependencies' }
    doclet
}

substitutions {
    substitute 'asm:asm' up_to '6' with 'org.ow2.asm:asm' at '+'
    substitute 'com.google.guava:guava' up_to '14.0.1' with 'com.google.guava:guava-jdk5' at '+'
}

dependencies {

    compile "com.miglayout:miglayout-swing:$miglayoutVersion"
    compile "it.unibo.alchemist:alchemist-engine:$engineVersion"
    compile "it.unibo.alchemist:alchemist-enginedependentmodel:$enginedepVersion"
    compile "it.unibo.alchemist:alchemist-implementationbase:$implbaseVersion"
    compile "it.unibo.alchemist:alchemist-incarnations:$incarnationsVersion"
    compile "it.unibo.alchemist:alchemist-maps:$mapsVersion"
    compile "org.apache.commons:commons-math3:[3, 4)"
    compile "org.mapsforge:mapsforge-map-awt:$mapsforgeVersion"
    compile "org.jfree:jfreesvg:$jfreesvgVersion"
    compile "org.jfree:jfreechart:$jfreechartVersion"
    compile "org.slf4j:slf4j-api:$slf4jVersion"
    
    testCompile "junit:junit:$junitVersion"
    
    runtime "ch.qos.logback:logback-classic:$logbackVersion"

    doclet "org.jboss.apiviz:apiviz:$apivizVersion"

    pmd(
            "net.sourceforge.pmd:pmd-core:$pmdVersion",
            "net.sourceforge.pmd:pmd-vm:$pmdVersion",
            "net.sourceforge.pmd:pmd-plsql:$pmdVersion",
            "net.sourceforge.pmd:pmd-jsp:$pmdVersion",
            "net.sourceforge.pmd:pmd-xml:$pmdVersion",
            "net.sourceforge.pmd:pmd-java:$pmdVersion"
            )
}

// Javadoc Configuration

task aggregateJavadoc(type: Javadoc) {
    source configurations.doc.collect { zipTree(it) }
    source sourceSets.main.allJava
    classpath = sourceSets.main.output + sourceSets.main.compileClasspath
    include '**/*.java'
    destinationDir file("$project.buildDir/docs/javadoc/")
    failOnError = false
    options.showAll()
    options.addBooleanOption('nopackagediagram', true)
    options.addStringOption('Xdoclint:none', '-quiet')
    configure(options) {
        windowTitle "$projectLongName version $project.version Javadoc API"
        docTitle "$projectLongName $project.version reference API"
        links 'http://docs.oracle.com/javase/8/docs/api/'
        links 'http://trove4j.sourceforge.net/javadocs/'
        doclet 'org.jboss.apiviz.APIviz'
        docletpath file(configurations.doclet.asPath)
    }
}

// Artifacts configuration

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: aggregateJavadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

signing { sign configurations.archives }

// Eclipse configuration

eclipse {
    classpath {
        downloadJavadoc = true
        downloadSources = true
    }
}

// FindBugs configuration

findbugs {
    ignoreFailures = true
    effort = "max"
    reportLevel = "low"
}

tasks.withType(FindBugs) {
    reports {
        xml.enabled = false
        html.enabled = true
    }
}

// PMD configuration

pmd {
    ignoreFailures = true
    ruleSets = []
    ruleSetFiles = files("pmd.xml")
    targetJdk = pmdTargetJdk
    toolVersion = pmdVersion
}

tasks.withType(Pmd) {
    reports {
        xml.enabled = false
        html.enabled = true
    }
}

// Checkstyle configuration

checkstyle {
    ignoreFailures = true
    configFile = new File("style.xml")
}

checkstyleMain << {
    ant.xslt(in: reports.xml.destination,
    style: new File("$project.projectDir/checkstyle-noframes-sorted.xsl"),
    out: new File(reports.xml.destination.parent, 'main.html'))
}

checkstyleTest << {
    ant.xslt(in: reports.xml.destination,
    style: new File("$project.projectDir/checkstyle-noframes-sorted.xsl"),
    out: new File(reports.xml.destination.parent, 'main.html'))
}

// Upload configuration

signArchives.onlyIf { Boolean.parseBoolean(signArchivesIsEnabled) }

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }
            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }
            pom.project {
                name artifactId
                description projectDescription
                packaging 'jar'
                url "$scmRootUrl/$artifactId"
                licenses {
                    license {
                        name licenseName
                        url licenseUrl
                    }
                }
                developers {
                    developer {
                        name 'Danilo Pianini'
                        email 'danilo.pianini@unibo.it'
                        url 'http://danilopianini.apice.unibo.it/'
                    }
                    developer {
                        name 'Giovanni Ciatto'
                        email 'giovanni.ciatto@studio.unibo.it'
                        url 'https://bitbucket.org/gciatto'
                    }
                    developer {
                        name 'Gianluca Turin'
                        email 'turin.gianluca@educ.di.unito.it'
                        url 'https://github.com/giaku'
                    }
                    developer {
                        name 'Giacomo Scaparrotti'
                        email 'tgiacomo.scaparrotti@studio.unibo.it'
                        url 'https://github.com/gscaparrotti'
                    }
                }
                scm {
                    url "$scmRootUrl/$artifactId"
                    connection "$scmType:$scmLogin/$scmRepoName"
                    developerConnection "$scmType:$scmLogin/$scmRepoName"
                }
            }
        }
    }
}

defaultTasks 'wrapper', 'clean', 'build', 'check', 'assemble', 'install', 'aggregateJavadoc', 'buildDashboard'