-
Notifications
You must be signed in to change notification settings - Fork 32
/
chess.sed
1523 lines (1231 loc) · 51.1 KB
/
chess.sed
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#n
# sed chess by Evgeny Stepanischev (http://bolknote.ru) Aug 2013
1s/.*/\
@\
figures()\
board()\
label(loop)\
label(blackkingmove)\
input()\
move-white()\
check-black-king-exists()\
select-figures(K)\
make-fake-kings()\
select-figures(p)\
label(pawnwhite)\
iter-pawn()\
break-if-end(pawnwhite)\
delete-last-board()\
store-only-iter()\
back(pawnwhite)\
select-figures(q)\
label(queenwhite)\
iter-queen()\
break-if-end(queenwhite)\
delete-last-board()\
store-only-iter()\
back(queenwhite)\
select-figures(k)\
label(kingwhitw)\
iter-king()\
break-if-end(kingwhite)\
delete-last-board()\
store-only-iter()\
back(kingwhite)\
select-figures(i)\
label(bishopwhite)\
iter-bishop()\
break-if-end(bishopwhite)\
delete-last-board()\
store-only-iter()\
back(bishopwhite)\
select-figures(n)\
label(knightwhite)\
iter-knight()\
break-if-end(knightwhite)\
delete-last-board()\
store-only-iter()\
back(knightwhite)\
select-figures(r)\
label(rookwhite)\
iter-rook()\
break-if-end(rookwhite)\
delete-last-board()\
store-only-iter()\
back(rookwhite)\
check-mate()\
break-if-end(blackkingmove)\
move-black()\
check-white-king-exists()\
board()\
back(blackkingmove)\
board()\
select-figures(K)\
label(king)\
iter-king()\
break-if-end(king)\
set-array()\
estimate-white-pieces()\
set-array()\
estimate-black-pieces()\
estimate-black-king()\
sum-array()\
sub-array()\
delete-last-board()\
store-iter()\
back(king)\
select-figures(P)\
label(pawn)\
iter-pawn()\
break-if-end(pawn)\
set-array()\
estimate-white-pieces()\
set-array()\
estimate-black-pieces()\
estimate-black-pawn()\
sum-array()\
sub-array()\
delete-last-board()\
store-iter()\
back(pawn)\
select-figures(Q)\
label(queen)\
iter-queen()\
break-if-end(queen)\
set-array()\
estimate-white-pieces()\
set-array()\
estimate-black-pieces()\
estimate-black-queen()\
sum-array()\
sub-array()\
delete-last-board()\
store-iter()\
back(queen)\
select-figures(I)\
label(bishop)\
iter-bishop()\
break-if-end(bishop)\
set-array()\
estimate-white-pieces()\
set-array()\
estimate-black-pieces()\
estimate-black-bishop()\
sum-array()\
sub-array()\
delete-last-board()\
store-iter()\
back(bishop)\
select-figures(N)\
label(knight)\
iter-knight()\
break-if-end(knight)\
set-array()\
estimate-white-pieces()\
set-array()\
estimate-black-pieces()\
estimate-black-knight()\
sum-array()\
sub-array()\
delete-last-board()\
store-iter()\
back(knight)\
select-figures(R)\
label(rook)\
iter-rook()\
break-if-end(rook)\
set-array()\
estimate-white-pieces()\
estimate-black-pieces()\
sub-array()\
delete-last-board()\
store-iter()\
back(rook)\
find-best-move()\
move-black()\
board()\
check-white-king-exists()\
select-figures(k)\
make-fake-kings()\
select-figures(P)\
label(pawnmoves)\
iter-pawn()\
break-if-end(pawnmoves)\
delete-last-board()\
store-only-iter()\
back(pawnmoves)\
select-figures(Q)\
label(queenmoves)\
iter-queen()\
break-if-end(queenmoves)\
delete-last-board()\
store-only-iter()\
back(queenmoves)\
select-figures(K)\
label(kingmoves)\
iter-king()\
break-if-end(kingmoves)\
delete-last-board()\
store-only-iter()\
back(kingmoves)\
select-figures(I)\
label(bishopmoves)\
iter-bishop()\
break-if-end(bishopmoves)\
delete-last-board()\
store-only-iter()\
back(bishopmoves)\
select-figures(N)\
label(knightmoves)\
iter-knight()\
break-if-end(knightmoves)\
delete-last-board()\
store-only-iter()\
back(knightmoves)\
select-figures(R)\
label(rookmoves)\
iter-rook()\
break-if-end(rookmoves)\
delete-last-board()\
store-only-iter()\
back(rookmoves)\
check-mate()\
back(loop)\
/
# оценки запрограммированы по матрицам из книги
# «Программирование шахмат и других логических игр» Корнилова Евгения Николаевича
# переформатирование команд
1s/ *//g; 1s/\n\n*/ /g; 1s/^ //
# обработка поступающей команды
1!{
/^\([a-h][1-8]\) *\([a-h][1-8]\)$/ {
s//\1 \2/
# добавляем полученные значения впереди стека исполнения
G; s/\n/ /
# переходим на исполнение команд
b @
}
# игрок хочет выйти
/^q/ q
# введена какая-то ерунда, стираем и возвращаем стек команд
i\
[12H[J[1A
s/.*//
g
b
}
:@
s/@\([^ ]* \)/\1@/
# начать массив
/@set-array()/ {
s/^/ARRAY /
b @
}
# метка
/@label(/ {
b @
}
# переход к метке
/@back(/ {
s/label(\([^)]*\))\(.*\)@back(\1)/@label(\1)\2back(\1)/
b @
}
# выход из цикла, если на вершине END
/@break-if-end(/ {
/^END */{
s///
s/@break-if-end(\([^)]*\))\(.*\)back(\1)/break-if-end(\1)\2@back(\1)/
}
b @
}
# ввод данных
/@input()/ {
h; b
}
# удаление последней копии доски
/@delete-last-board()/ {
s/\(.*\)Board:[^ ]* */\1/
b @
}
# дублирование доски
/@copy-board()/ {
s/\(Board:[^ ]*\)/\1 \1/
b @
}
# генерация начального состояния доски
/@figures()/ {
# формат: XYFig
# координаты белых тут и дальше должны идти НИЖЕ чёрных
# БОЛЬШИЕ — чёрные, маленькие — белые
s/^/Board:\
a8Rb8Nc8Id8Qe8Kf8Ig8Nh8R\
a7Pb7Pc7Pd7Pe7Pf7Pg7Ph7P\
a6 b6 c6 d6 e6 f6 g6 h6 \
a5 b5 c5 d5 e5 f5 g5 h5 \
a4 b4 c4 d4 e4 f4 g4 h4 \
a3 b3 c3 d3 e3 f3 g3 h3 \
a2pb2pc2pd2pe2pf2pg2ph2p\
a1rb1nc1id1qe1kf1ig1nh1r /
# пробел в конце нужен!
# s/^/Board:\
# a8 b8 c8 d8 e8Kf8 g8 h8r\
# a7 b7 c7 d7 e7 f7 g7 h7 \
# a6 b6 c6 d6 e6nf6 g6 h6 \
# a5 b5 c5 d5 e5 f5 g5 h5 \
# a4 b4 c4 d4 e4 f4 g4 h4 \
# a3 b3 c3 d3 e3 f3 g3 h3 \
# a2 b2 c2 d2 e2 f2 g2 h2k\
# a1 b1 c1 d1 e1 f1 g1 h1 /
s/\n//g
b @
}
# вывод доски
/@board()/ {
# сохраняем стек команд
h
# убираем всё, кроме доски (берём всегда последнюю доску)
s/.*Board://
s/ .*$//
# расшифровываем доску
# Pawn, Queen, King, bIshop, kNight, Rook, Zero — псевдокороль для опредления мата и шаха
s/..z//g
y/pqkinrPQKINR12345678abcd/♟♛♚♝♞♜♙♕♔♗♘♖987654323579/
s/\([1-9e-h]\)\([1-9]\)\(.\)/[\2;\1H\3 /g
# расцвечиваем
s/[8642];[37eg]H/&[48;5;209;37;1m/g
s/[9753];[37eg]H/&[48;5;94;37;1m/g
s/[8642];[59fh]H/&[48;5;94;37;1m/g
s/[9753];[59fh]H/&[48;5;209;37;1m/g
# двузначные числа
s/e/11/g;s/f/13/g;s/g/15/g;s/h/17/g
s/$/[0m[11H/
# выводим доску и возвращаем всё как было
i\
[2J[1;3Ha b c d e f g h\
8\
7\
6\
5\
4\
3\
2\
1\
\
Введите команду
p
g
b @
}
# делаем ход по введённым пользователем данным
/@move-white()/ {
# гарды основных регулярок (их нужно тщательно защищать от несрабатываний,
# иначе sed выдаст ошибку и остановится)
# вычищаем всё, кроме доски и первых двух значений
h; s/\([^ ]*\) \([^ ]*\).*Board:\([^ ]*\).*/\1 \2 \3/
# выделяем указанные клетки
s/\([^ ]*\) [^ ]* .*\(\1.\)/&(1:\2)/
s/[^ ]* \([^ ]*\) .*\(\1.\)/&(2:\2)/
# теперь они имеют формат:
# номер_по_порядку_ввода:XYФигура
s/.*(\(.....\)).*(\(.....\)).*/\1 \2/
# теперь надо проверить:
# 1. что берём не чужую и не пустую фигуру
/1:..[PQKINR ]/ {
g; s/[^ ]* [^ ]* *//; b @
}
# 2. не кладём на место своей фигуры
/2:..[pqkinr]/ {
g; s/[^ ]* [^ ]* *//; b @
}
# порядок такой:
# указанные координаты у найденных фигур меняем между собой
# если ход будет вперёд…
/2:.*1:/ {
g
# 1 2 3 4 5
/\([^ ]*\) \([^ ]*\) \(.*Board:[^ ]*\)\2.\([^ ]*\)\1\([pqkinr]\)/ {
s//\3\1 \4\2\5/
b move-white::checkpawn
}
}
# ход назад
g
# 1 2 3 4 5
s/\([^ ]*\) \([^ ]*\) \(.*Board:[^ ]*\)\1\([pqkinr]\)\([^ ]*\)\2./\3\2\4\5\1 /
# проверяем, не оказалась ли пешка на 8-й горизонтали, если да, то надо преобразовать
# её в ферзя (за ход может быть только одна такая пешка)
:move-white::checkpawn
s/\([a-h]8\)p/\1q/
b @
}
# количество оставшихся фигур
/@count-pieces()/ {
h
# убираем всё, кроме доски
s/.*Board://
s/ .*$//
# убираем всё, кроме белых фигур
s/[^pqkinrPQKINR]//g
# считаем
s/./1/g
# возвращаем стек команд
G
# после G появился перевод строки, убираем его
s/\n/ /
b @
}
#оценочная функция имеющихся чёрных фигур
/@estimate-black-pieces()/ {
# пешка — 100, слон и конь — 300, ладья — 500, ферзь — 900, король — 9000,
# ещё 9000 — псевдофигура чёрных, чтобы не было переполнения = 21900
# очистка всего лишнего
h; s/.*Board://; s/ .*$//
# убираем всё, кроме подсчитываемых фигур
s/[^PINRQK]//g
# считаем количество * коэффициент фигуры (ферзь Q — единственный, но может появиться ещё через пешку)
s/P/1/g; s/[NI]/111/g; s/R/11111/g; s/Q/111111111/g
# король, ставим вперёд к псевдофигуре
s/^\(.*\)K/HHHHHHHHH\1/
# чёрная псевдофигура
s/^/HHHHHHHHH/
# группируем сотни и тысячи
s/1111111111/H/g; s/HHHHHHHHHH/T/g
# вставляем двоеточия
s/\(.\)\1*/&:/g
# если нет единиц, в конец — ещё одно двоеточие
/1/ ! s/$/:/
# если нет сотен, то до единиц или последнего двоеточия — ещё двоеточие
/H/ ! s/[1:]/:&/
y/HT/11/; s/$/:B/
# добавляем к сохранённому стеку
G; s/\n/ /
b @
}
#оценочная функция имеющихся белых фигур
/@estimate-white-pieces()/ {
# пешка — 100, слон и конь — 300, ладья — 500, ферзь — 900, король — 9000
# очистка всего лишнего
h; s/.*Board://; s/ .*$//
# убираем всё, кроме подсчитываемых фигур
s/[^pinrqk]//g
# считаем количество * коэффициент фигуры (ферзь q — единственный, но может появиться ещё через пешку)
s/p/1/g; s/[ni]/111/g; s/r/11111/g; s/q/111111111/g
# король, ставим вперёд
s/^\(.*\)k/HHHHHHHHH\1/
# группируем сотни и тысячи
s/1111111111/H/g; s/HHHHHHHHHH/T/g
# вставляем двоеточия
s/\(.\)\1*/&:/g
# если нет единиц, в конец — ещё одно двоеточие
/1/ ! s/$/:/
# если нет сотен, то до единиц или последнего двоеточия — ещё двоеточие
/H/ ! s/[1:]/:&/
y/HT/11/; s/$/:B/
# добавляем к сохранённому стеку
G; s/\n/ /
b @
}
#для отладки: вывод текущего стека
/@log()/ {
l
q
}
/@l()/ {
h
l
w chess.log
g
}
#оценочная функция для позиции чёрных пешек
/@estimate-black-pawn()/ {
# очистка всего лишнего
h; s/.*Board://; s/ .*$//
# оставляем только чёрные и белые пешки, перекодируем их в понятные координаты
# теперь пешки записаны вот так: XЦвет (где Цвет — Black или White), разделены пробелом
s/[a-h][1-8][^Pp]//g; y/Ppabcdefgh/BW12345678/; s/\([1-8]\)[1-8]/ \1/g
# → Этап 1
# ищем чёрные пешки, на вертикали у которых стоят белые, координаты белых идут
# всегда ПОСЛЕ координат чёрных
:estimate-black-pawn::black
/\([1-8]\)B\(.*\1\)W/ {
s//\1b\2W/
b estimate-black-pawn::black
}
# → Этап 2.1
# переводим координаты в последовательности длины X
:estimate-black-pawn::x
/[2-8]/ {
s/[2-8]/1&/g
y/2345678/1234567/
b estimate-black-pawn::x
}
# → Этап 2.2
# ищем пешки, не отсеянные на этапе 1, у которых на соседней линии слева стоят белые
:estimate-black-pawn::left
/\( 1*\)B\(.*\11\)W/ {
s//\1b\2W/
b estimate-black-pawn::left
}
# → Этап 2.3
# ищем пешки, не отсеянные на этапе 2, у которых на соседней линии справа стоят белые
:estimate-black-pawn::right
/ 1\(1*\)B\(.* \1\)W/ {
s// 1\1b\2W/
b estimate-black-pawn::right
}
# В итоге, W — белые пешки, b — чёрные, B — чёрные свободные пешки
# избавляемся от несвободных и белых пешек
s/ [^ ]*[Wb]//g
# → Этап 3
# считаем стоимости чёрных свободных пешек
s/ 1B//; s/ 11B/ ::11111B/; s/ 111B/ :1:B/; s/ 1111B/ :1:11111B/; s/ 11111B/ :11:B/
s/ 111111B/ :111:B/; s/ 1111111B/ 1:1111:B/; s/ 11111111B//
# → Этап 4
# сохраняем полученное, грузим стек обратно, вырезаем доску и оставляем чёрные пешки с координатами
G; h; s/.*Board://; s/ .*$//; s/[a-h][1-8][^p]//g
# оцениваем позиции всех пешек
s/.[81]p/::B/g
s/[abcfgh]7p/::1111B/g; s/[de]7p/::B/g
s/[ah][65]p/::111111B/g; s/[bg][65]p/::11111111B/g; s/[cf]6p/::11B/g; s/[de]6p/:1:B/g
s/[bg]5p/:1:11B/g; s/[cf]5p/:1:111111B/g; s/[de]5p/:11:1111B/g
s/[ah]4p/::11111111B/g; s/[bg]4p/:1:11B/g; s/[cf]4p/:1:111111B/g; s/[de]4p/:11:1111B/g
s/[ah][32]p/:1:11B/g; s/[bg][32]p/:1:111111B/g; s/[cf][32]p/:11:1111B/g; s/[de][32]p/:111:11B/g
# вставляем пробелы между оценками
s/B/& /g; s/^/ /
# → Этап 5
# возвращаем сохранённые оценки, убираем остатки стека
G; s/\n\(.*\)\n.*/ \1/
# добавляем к сохранённому стеку, вычищаем наш мусор, который мы складывали выше —
# там второй строкой лежат оценки
G; s/\n.*\n/ /
b @
}
#оценочная функция для позиции чёрного короля
/@estimate-black-king()/ {
h; s/.*Board://; s/ .*$//
# выделяем короля
s/[a-h][1-8][^K]//g
# считаем его вес (матрица конца игры)
s/[ah][18]./::/
s/[de][54]./:111:111111/
s/[cf][54]./:111:/; s/[de][63]./:111:/
s/[bg][54]./:11:1111/; s/[de][72]./:11:1111/; s/[cf][63]./:11:1111/
s/[de][18]./:1:11111111/; s/[ah][54]./:1:11111111/; s/[cf][72]./:1:11111111/; s/[bg][63]./:1:11111111/
s/[bg][72]./:1:11/; s/[ah][63]./:1:11/; s/[cf][81]./:1:11/
s/[a-h][1-9]./::111111/
G; s/\n/B /
b @
}
#оценочная функция для позиции чёрного коня
/@estimate-black-knight()/ {
h; s/.*Board://; s/ .*$//
# выделяем коней
s/[a-h][1-8][^N]//g
# считаем их вес
s/[ah][18]./::B/g
s/[de][54]./:111:11B/g
s/[cf][54]./:11:11111111B/g; s/[de][63]./:11:11111111B/g
s/[cf][36]./:11:1111B/g
s/[bg][54]./:11:B/g; s/[de][72]./:11:B/g; s/[cf][63]./:11:B/g
s/[de][18]./:1:B/g; s/[ah][54]./:1:B/g; s/[cf][72]./:1:B/g; s/[bg][63]./:1:B/g
s/[bg][72]./::11111111B/g; s/[ah][63]./::11111111B/g; s/[cf][81]./::11111111B/g
s/[a-h][1-9]./::1111B/g
s/B/& /g; G; s/ *\n/ /
b @
}
#оценочная функция для позиции чёрного слона
/@estimate-black-bishop()/ {
h; s/.*Board://; s/ .*$//
# выделяем слонов
s/[a-h][1-8][^I]//g
# считаем их вес
s/[a-h][81]./:::1:1111B/g; s/[ah][1-8]./:::1:1111B/g
s/[bg][72]./:::11:11B/g; s/[c-f][3-6]/:::11:11B/g
s/[a-h][1-9]./:::1:11111111B/g
s/B/& /; G; s/\n/ /
b @
}
#оценочная функция для позиции чёрной королевы (ферзя)
/@estimate-black-queen()/ {
h; s/.*Board://; s/ .*$//
# выделяем ферзя и вражеского короля
s/[a-h][1-8][^Qk]//g
# если одной из фигур на поле нет, возврат
/Q/,/k/ ! {
g; b @
}
# короля выдвигаем вперёд
s/\(.*\)\(..k\)\(.*\)/\2\1\3/
# если у нас имеется второй ферзь, то ставим его через разделитель
# и впереди к нему лепим короля
s/\(..k\)\(..Q\)\(..Q\)/ \1\2\# \1\3/
# фигуры убираем, координаты к числам, расставляем пробелы вокруг чисел для ограничения
y/abcdefgh/12345678/; s/\([1-9]\)\(.\)./\1 \2 /g
# группируем координаты, получится X1 X2 Y1 Y2 (на двух строках)
# у нас захватывается по три значения, но путаницы не будет, т.к. используются пробелы,
# а между парами чисел — «решётка»
s/\([1-8]\) \([1-8]\) \([1-8]\)/\1 \3 \2/g
# переводим координаты в последовательности длины значений координат
:estimate-black-queen::xy
/[2-8]/ {
s/[2-8]/1&/g
y/2345678/1234567/
b estimate-black-queen::xy
}
# должно получиться (8 — наибольшее растояние):
# 8 - (XM-Xm) + 8 - (YM-Ym) => 16-XM+Xm-YM+Ym => 16-(XM+YM)+(Xm+Ym)
# сортировка — бо́льшая координата вперёд
s/ \(11*\) \(\111*\)/ \2 \1/g
# получается 4 числа для каждой пары фигур: XM Xm YM Ym, нужно сложить их попарно,
# вторую двойку переносим вперёд и складываем с 16
s/\(11*\) \(11*\) \(11*\) \(11*\)/1111111111111111\2\4 \1\3/g
# вычитаем вторую координату из первой
s/\(11*\)\(1*\) \1/\2/g
# объединяем цисла до обеим фигурам
s/[# ]//g
# группируем сотни и тысячи
s/1111111111/H/g; s/HHHHHHHHHH/T/g
# вставляем двоеточия
s/\(.\)\1*/&:/g
# если нет единиц, в конец — ещё одно двоеточие
/1/ ! s/$/:/
# если нет сотен, то до единиц или последнего двоеточия — ещё двоеточие
/H/ ! s/[1:]/:&/
y/HT/11/
G; s/\n/B /
b @
}
# суммированние чисел на стеке, пока не встретится слово ARRAY
/@sum-array()/ {
h
/ARRAY.*/ {
s///
s/$/ ::::::S/
:sum-array::shift
/[1:][1:]*B/ {
# сложение разряда
:sum-array::sum
/11*B/ {
s/\(11*\)B\(.*\)\(1*\)S/B\2\1\3S/
s/:1111111111\(1*\)S/1:\1S/
b sum-array::sum
}
# сдвиг разряда
s/:B/B/g; s/:\(1*\)S/S \1:/
b sum-array::shift
}
s/:\(1*\)S/S \1:/; s/[^1:]//g
G; s/ARRAY/#&/; s/:\n.*#ARRAY */B /
}
b @
}
# вычитание чисел на стеке из первого, пока не встретится слово ARRAY
/@sub-array()/ {
/ *ARRAY.*/ {
h; s///
# у первого числа заменяем букву, чтобы отличать
s/B */M /
# у каждого числа впереди должен быть ограничитель
s/^/:/; s/ / :/g
# у первого числа снимаем самый младший разряд
s/:\(1*\)\(M.*\)/:\2 :\1#S/
:sub-array::loop
# теперь пройдёмся по младшим разрядам оставшихся чисел
:sub-array::minus
/:\(11*\)\(B.*\) :\1\(1*\)#S/ {
s//:\2 :\3#S/
b sub-array::minus
}
# младшие разряды для вычитания остались?
/:11*B/ {
# переносим разряды вычитаемого на младший
:sub-array::cy
# если переносить нечего, то всё, получается число меньше нуля,
# возвращаем ноль, выходим
/1.*M/ ! {
s/.*/:::B/
b sub-array::end
}
s/\(.*\)1:\(.*M\)/\1:1111111111\2/
/1M/ ! b sub-array::cy
# добавляем к вычитаемому
s/:\(1*\)\(M.*\) \(:.*\)#S/:\2 \3\1#S/
b sub-array::minus
}
# срезаем у всех по пустому теперь разряду, у тех, у кого их не осталось, убираем
s/:\([BM]\)/\1/g; s/ :*B//g
# берём следующий разряд
s/:\(1*\)\(M.*\) \([^ ]*\)#S/:\2 :\1#S \3S/
# если осталось что вычитать, вычитаем
/B/ b sub-array::loop
# убираем лишнее, нормализируем
s/[#MS ]//g; s/://
:sub-array::end
G; s/ARRAY/#&/; s/\n.*#ARRAY */B /
}
b @
}
# выбор указанной фигуры (вернётся в виде строки)
# XYF__XYF__ где F — наименование фигуры, __ — место под перебор позиции
/@select-figures(.)/ {
h
# убираем из данных всё лишнее, параметр помечаем маркером
s/@select-figures(\(.\))\(.*\)/\2 Selected:\1/
s/.*Board://
s/ .*Selected:/ Selected:/
# выделяем из доски то, что указал пользователь
:select-figures::select
/\([a-h][0-9]\)\(.\)\(.* Selected:\2\)/ {
s//\3\1\2__/
b select-figures::select
}
# убираем маркер и изувеченную доску
s/.*Selected:.//
# возвращаем стек назад
G; s/\n/END /
b @
}
/@iter-knight()/ {
# убираем коня, который ход закончил
s/^...XX//
# выходим, если ходить нечем
/^END/ b @
# выделяем первого коня
h; s/\(.....\).*/\1/
# кодировка ходов: __ — не был сделан, XX — сделаны все возможные
# Left, Down, Up, Right, первым пишется ход на две клетки, например:
# LU — влево на две, вверх на одну
/__/ {
s//LU/
# сдвигаем координату X-2, Y+1, 0 — признак, что ход невозможен
y/abcdefgh/00abcdef/
y/12345678/23456780/
b common::go
}
/LU/ {
s//UL/
# X-1, Y+2
y/abcdefgh/0abcdefg/
y/12345678/34567800/
b common::go
}
/UL/ {
s//UR/
# X+1, Y+2
y/abcdefgh/bcdefgh0/
y/12345678/34567800/
b common::go
}
/UR/ {
s//RU/
# X+2, Y+1
y/abcdefgh/cdefgh00/
y/12345678/23456780/
b common::go
}
/RU/ {
s//RD/
# X+2, Y-1
y/abcdefgh/cdefgh00/
y/12345678/01234567/
b common::go
}
/RD/ {
s//DR/
# X+1, Y-2
y/abcdefgh/bcdefgh0/
y/12345678/00123456/
b common::go
}
/DR/ {
s//DL/
# X-1, Y-2
y/abcdefgh/0abcdefg/
y/12345678/00123456/
b common::go
}
/DL/ {
s//XX/
# X-2, Y-1
y/abcdefgh/00abcdef/
y/12345678/01234567/
b common::go
}
b common::go
}
# король ходит на одну клетку куда угодно N
# кодировка по сторонам света W E
# __ → NN → EN → EE → SE → SS → WS → WW → NW → XX S
/@iter-king()/ {
# убираем короля, который ход закончил
s/^...XX//
# выходим, если ходить нечем
/^END/ b @
# выделяем первого (и единственного) короля
h; s/\(.....\).*/\1/
# текущую выбранную позицию меняем на следующую
s/$/ __NNENEESESSWSWWNWXX/
s/\(..\) \(.*\1\)\(..\)/\3 \2\3/; s/ .*//
# заменяем координты, согласно выбранной позиции
# Y+1
/N/ y/12345678/23456780/
# Y-1
/S/ y/12345678/01234567/
# X-1
/W/ y/abcdefgh/0abcdefg/
# X+1
/E/ y/abcdefgh/bcdefgh0/
b common::go
}
# ладья, ходит по вертикали или горизонтали на любое количество ходов, N
# если никто не стоит на пути W E
# ходит начинаем с текущей координаты в указанную сторону S
/@iter-rook()/ {
# убираем ладью, которая ход закончила
s/^...XX//
# выходим, если ходить нечем
/^END/ b @
# выделяем первую ладью
h; s/\(.....\).*/\1/
# первое наше направление — восток, потом идём по следующим направлениям
/__/ s/\(\(.\).*\)__/\1E\2/
/E0/ s/\(\(.\).*\)E./\1W\2/
/W0/ s/\(.\(.\).*\)W./\1N\2/
/N0/ s/\(.\(.\).*\)N./\1S\2/
s/S0/XX/
/E/ y/abcdefgh/bcdefgh0/
/W/ y/abcdefgh/0abcdefg/
/S/ y/12345678/01234567/
/N/ y/12345678/23456780/
# переписываем состояние в координаты выбранной фигуры, так как фигура хода пропадёт
/[SN]/ s/\(.\).\(..\(.\)\)/\1\3\2/
/[WE]/ s/.\(...\(.\)\)/\2\1/
/[0X]/ ! {
# возвращаем стек, убираем всё, что за и перед доской на стеке
s/$/#/; G; s/\n.*\(Board:[^ ]*\).*/\1/
# если на выбранной позиции псевдокороль, больше ни на что не обращаем внимания
/^\(..\).*\1z/ ! {
# проверка, не стоит ли на выбранной позиции своя фигура, если стоит, прекращаем скан сразу
s/^\(..\)R\(.\).*\(\1[PQKINR]\).*/00R\20#\3/
s/^\(..\)r\(.\).*\(\1[pqkinr]\).*/00r\20#\3/
# если же там стоит чужая фигура, то двигаться можно, а ходить за неё — нет
s/^\(..\)R\(.\).*\(\1[pqkinr]\).*/\1R\20#\3/
s/^\(..\)r\(.\).*\(\1[PQKINR]\).*/\1r\20#\3/
}
s/#.*//
}
b common::go