forked from grpc/grpc-java
/
build.gradle
130 lines (111 loc) · 4.06 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
plugins {
id "java"
id "maven-publish"
id "com.github.johnrengelman.shadow"
id "com.google.protobuf"
id "ru.vyarus.animalsniffer"
}
description = "gRPC: XDS plugin"
[compileJava].each() {
it.options.compilerArgs += [
// valueOf(int) in RoutingPriority has been deprecated
"-Xlint:-deprecation",
]
}
evaluationDependsOn(project(':grpc-core').path)
dependencies {
implementation project(':grpc-protobuf'),
project(':grpc-stub'),
project(':grpc-core'),
project(':grpc-services'),
project(path: ':grpc-alts', configuration: 'shadow'),
libraries.gson,
libraries.re2j
def nettyDependency = implementation project(':grpc-netty')
implementation (libraries.opencensus_proto) {
// prefer our own versions instead of opencensus_proto's
exclude group: 'com.google.protobuf', module: 'protobuf-java'
exclude group: 'io.grpc', module: 'grpc-protobuf'
exclude group: 'io.grpc', module: 'grpc-stub'
}
implementation (libraries.protobuf_util) {
// prefer our own versions instead of protobuf-util's dependency
exclude group: 'com.google.guava', module: 'guava'
exclude group: 'com.google.errorprone', module: 'error_prone_annotations'
}
testImplementation project(':grpc-core').sourceSets.test.output
compileOnly libraries.javax_annotation,
// At runtime use the epoll included in grpc-netty-shaded
libraries.netty_epoll
testImplementation project(':grpc-testing'),
project(':grpc-testing-proto'),
libraries.netty_epoll
testImplementation (libraries.guava_testlib) {
exclude group: 'junit', module: 'junit'
}
shadow configurations.implementation.getDependencies().minus([nettyDependency])
shadow project(path: ':grpc-netty-shaded', configuration: 'shadow')
signature "org.codehaus.mojo.signature:java17:1.0@signature"
testRuntimeOnly libraries.netty_tcnative
}
sourceSets {
main {
proto {
srcDir 'third_party/envoy/src/main/proto'
srcDir 'third_party/protoc-gen-validate/src/main/proto'
srcDir 'third_party/udpa/src/main/proto'
}
}
}
configureProtoCompilation()
jar {
classifier = 'original'
}
javadoc {
exclude 'io/grpc/xds/internal/**'
// At the moment there is no public API. Should probably clean up the class structure to reduce
// how much is exposed
exclude 'io/grpc/xds/**'
}
shadowJar {
classifier = null
dependencies {
include(project(':grpc-xds'))
}
relocate 'com.github.udpa', 'io.grpc.xds.shaded.com.github.udpa'
relocate 'io.envoyproxy', 'io.grpc.xds.shaded.io.envoyproxy'
relocate 'io.grpc.netty', 'io.grpc.netty.shaded.io.grpc.netty'
relocate 'io.netty', 'io.grpc.netty.shaded.io.netty'
exclude "**/*.proto"
}
jacocoTestReport {
classDirectories.from = sourceSets.main.output.collect {
fileTree(dir: it,
exclude: [
'**/com/github/**',
'**/envoy/annotations/**',
'**/io/envoyproxy/**',
'**/udpa/annotations/**',
])
}
}
publishing {
publications {
maven(MavenPublication) {
artifact shadowJar
artifacts.removeAll { it.classifier == 'original' }
pom.withXml {
def dependenciesNode = new Node(null, 'dependencies')
project.configurations.shadow.allDependencies.each { dep ->
def dependencyNode = dependenciesNode.appendNode('dependency')
dependencyNode.appendNode('groupId', dep.group)
dependencyNode.appendNode('artifactId', dep.name)
def version = (dep.name == 'grpc-netty-shaded') ? '[' + dep.version + ']' : dep.version
dependencyNode.appendNode('version', version)
dependencyNode.appendNode('scope', 'compile')
}
asNode().dependencies[0].replaceNode(dependenciesNode)
}
}
}
}