-
Notifications
You must be signed in to change notification settings - Fork 51
/
AbstractFunctionalTest.groovy
250 lines (215 loc) · 7.8 KB
/
AbstractFunctionalTest.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
/*
* Copyright (c) 2021, Oracle and/or its affiliates. All rights reserved.
* DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
*
* The Universal Permissive License (UPL), Version 1.0
*
* Subject to the condition set forth below, permission is hereby granted to any
* person obtaining a copy of this software, associated documentation and/or
* data (collectively the "Software"), free of charge and under any and all
* copyright rights in the Software, and any and all patent rights owned or
* freely licensable by each licensor hereunder covering either (i) the
* unmodified Software as contributed to or provided by such licensor, or (ii)
* the Larger Works (as defined below), to deal in both
*
* (a) the Software, and
*
* (b) any piece of software and/or hardware listed in the lrgrwrks.txt file if
* one is included with the Software each a "Larger Work" to which the Software
* is contributed by such licensors),
*
* without restriction, including without limitation the rights to copy, create
* derivative works of, display, perform, and distribute the Software and make,
* use, sell, offer for sale, import, export, have made, and have sold the
* Software and the Larger Work(s), and to sublicense the foregoing rights on
* either these or other terms.
*
* This license is subject to the following condition:
*
* The above copyright notice and either this complete permission notice or at a
* minimum a reference to the UPL must be included in all copies or substantial
* portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
* SOFTWARE.
*/
package org.graalvm.buildtools.gradle.fixtures
import org.gradle.testkit.runner.BuildResult
import org.gradle.testkit.runner.GradleRunner
import org.gradle.testkit.runner.TaskOutcome
import org.gradle.util.GFileUtils
import org.gradle.util.GradleVersion
import spock.lang.Specification
import spock.lang.TempDir
import java.nio.file.Path
abstract class AbstractFunctionalTest extends Specification {
@TempDir
Path testDirectory
String gradleVersion = testGradleVersion()
boolean debug
boolean IS_WINDOWS = System.getProperty("os.name", "unknown").contains("Windows");
boolean IS_LINUX = System.getProperty("os.name", "unknown").contains("Linux");
boolean IS_MAC = System.getProperty("os.name", "unknown").contains("Mac");
private StringWriter outputWriter
private StringWriter errorOutputWriter
private String output
private String errorOutput
private File initScript
BuildResult result
private static String testGradleVersion() {
String version = System.getProperty("gradle.test.version", GradleVersion.current().version)
if ("current" == version) {
version = GradleVersion.current().version
}
version
}
Path path(String... pathElements) {
Path cur = testDirectory
pathElements.each {
cur = cur.resolve(it)
}
cur
}
File file(String... pathElements) {
path(pathElements).toFile()
}
File getGroovyBuildFile() {
file("build.gradle")
}
File getKotlinBuildFile() {
file("build.gradle.kts")
}
File getGroovySettingsFile() {
file("settings.gradle")
}
File getKotlinSettingsFile() {
file("settings.gradle.kts")
}
File getBuildFile() {
groovyBuildFile
}
File getSettingsFile() {
groovySettingsFile
}
protected void withSample(String name) {
File sampleDir = new File("../samples/$name")
GFileUtils.copyDirectory(sampleDir, testDirectory.toFile())
}
void run(String... args) {
try {
result = newRunner(args)
.build()
} finally {
recordOutputs()
}
}
void outputContains(String text) {
assert output.contains(normalizeString(text))
}
void outputDoesNotContain(String text) {
assert !output.contains(normalizeString(text))
}
void errorOutputContains(String text) {
assert errorOutput.contains(normalizeString(text))
}
void tasks(@DelegatesTo(value = TaskExecutionGraph, strategy = Closure.DELEGATE_FIRST) Closure spec) {
def graph = new TaskExecutionGraph()
spec.delegate = graph
spec.resolveStrategy = Closure.DELEGATE_FIRST
spec()
}
private void recordOutputs() {
output = normalizeString(outputWriter.toString())
errorOutput = normalizeString(errorOutputWriter.toString())
}
private GradleRunner newRunner(String... args) {
assertInitScript()
outputWriter = new StringWriter()
errorOutputWriter = new StringWriter()
ArrayList<String> autoArgs = computeAutoArgs()
def runner = GradleRunner.create()
.forwardStdOutput(tee(new OutputStreamWriter(System.out), outputWriter))
.forwardStdError(tee(new OutputStreamWriter(System.err), errorOutputWriter))
.withPluginClasspath()
.withProjectDir(testDirectory.toFile())
.withArguments([*autoArgs, *args])
if (gradleVersion) {
runner.withGradleVersion(gradleVersion)
}
if (debug) {
runner.withDebug(true)
}
runner
}
private ArrayList<String> computeAutoArgs() {
List<String> autoArgs = [
"-S",
]
if (Boolean.getBoolean("config.cache")) {
autoArgs << '--configuration-cache'
}
autoArgs << "-I"
autoArgs << initScript.getAbsolutePath()
autoArgs
}
private static Writer tee(Writer one, Writer two) {
return TeeWriter.of(one, two)
}
void fails(String... args) {
try {
result = newRunner(args)
.buildAndFail()
} finally {
recordOutputs()
}
}
ProcessController execute(File executablePath) {
new ProcessController(executablePath, file("build"))
.execute()
}
private void assertInitScript() {
initScript = file("init.gradle")
initScript << """
allprojects {
repositories {
maven {
url = "\${providers.systemProperty('common.repo.url').forUseAtConfigurationTime().get()}"
}
mavenCentral()
}
}
"""
}
private class TaskExecutionGraph {
void succeeded(String... tasks) {
tasks.each { task ->
contains(task)
assert result.task(task).outcome == TaskOutcome.SUCCESS
}
}
void skipped(String... tasks) {
tasks.each { task ->
contains(task)
assert result.task(task).outcome == TaskOutcome.SKIPPED
}
}
void contains(String... tasks) {
tasks.each { task ->
assert result.task(task) != null: "Expected to find task $task in the graph but it was missing"
}
}
void doesNotContain(String... tasks) {
tasks.each { task ->
assert result.task(task) == null: "Task $task should be missing from the task graph but it was found with an outcome of ${result.task(task).outcome}"
}
}
}
private static String normalizeString(String input) {
input.replace("\r\n", "\n")
}
}