[Configuration cache] Filtered FC with mapped elements stored incorrectly

[gavra0]

Using this snippet:

abstract class Producer extends DefaultTask {
    @OutputDirectory
    abstract DirectoryProperty getOutputClasses()

    @TaskAction
    void doStuff() {
        File f = getOutputClasses().get().asFile
        f.mkdirs()

        new File(f, "some.txt") << "some text"
    }
}

TaskProvider<Producer> prod = tasks.register("prod", Producer.class) {
    it.getOutputClasses().set(new File(project.buildDir, "producerOutput"))
}

abstract class MyTask extends DefaultTask {
    @Classpath
    abstract ConfigurableFileCollection getClasses()

    @TaskAction
    void doStuff() {
        println getClasses().files
    }
}

Provider<List<Directory>> getDirectories(FileCollection fc, Directory projectDir) {
    fc.filter { File f ->
        f.isDirectory()
    }.elements.map {
        it.collect { fileSystemLocation ->
            projectDir.dir(fileSystemLocation.asFile.absolutePath)
        }
    }
}

FileCollection myFc = project.files(prod.map { it.getOutputClasses() })

tasks.register("myTask", MyTask.class) {
    it.getClasses().from(
            project.files(
                    getDirectories(myFc, project.layout.buildDirectory.get())
            )
    )
}

and running rm -rf .gradle/configuration-cache build && gw myTask --configuration-cache && gw myTask --configuration-cache shows that in the second run task prints nothing i.e getClasses() returns an empty file collection.

It is interested that if method getDirectories is changed to

Provider<List<Directory>> getDirectories(FileCollection fc, Directory projectDir) {
    fc.elements.map {
        it.findAll { FileSystemLocation fsl ->
            fsl.asFile.isDirectory()
        }.collect { fileSystemLocation ->
            projectDir.dir(fileSystemLocation.asFile.absolutePath)
        }
    }
}

this issue is fixed. However, in AGP something triggers it.findAll to run during configuration cache storing, causing the issue.

[eskatos]

Build scan of failing smoke tests with Santa Tracker and upgraded AGP with change revealing the issue
https://ge.gradle.org/s/lsihvi4oh5noi/tests/failed

[eskatos]

Fixed in #17578