-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle.kts
257 lines (226 loc) · 7.94 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
import net.ltgt.gradle.errorprone.errorprone
plugins {
application
`jvm-test-suite`
idea
jacoco
id("com.diffplug.spotless") version "6.7.2"
id("org.asciidoctor.jvm.convert") version "3.3.2"
id("nebula.ospackage") version "9.0.0"
id("net.ltgt.errorprone") version "2.0.2"
}
val appModuleName = "org.${project.name}"
val appMainClassName = "org.${project.name}.cli.Main"
application {
mainModule.set(appModuleName)
mainClass.set(appMainClassName)
applicationDefaultJvmArgs = listOf(
// the cli is short lived, so let's enable a fast JVM startup
"-XX:+NeverActAsServerClassMachine",
)
}
java {
toolchain {
languageVersion.set(JavaLanguageVersion.of(17))
}
}
spotless {
java {
palantirJavaFormat()
}
}
tasks.withType<AbstractArchiveTask>().configureEach {
// Enable reproducible builds
setPreserveFileTimestamps(false)
setReproducibleFileOrder(true)
}
tasks.processResources {
val props = mapOf("version" to project.version)
inputs.properties(props)
filesMatching("**/application.properties") {
expand(props)
}
}
tasks.withType<JavaCompile> {
options.errorprone.disable("InvalidParam")
}
repositories {
mavenCentral()
}
testing {
suites {
val test by getting(JvmTestSuite::class) {
useJUnitJupiter(libs.versions.junit.get())
dependencies {
compileOnly(libs.lombok)
annotationProcessor(libs.lombok)
implementation(libs.assertj)
}
}
val integrationTest by registering(JvmTestSuite::class) {
useJUnitJupiter(libs.versions.junit.get())
dependencies {
compileOnly(libs.lombok)
annotationProcessor(libs.lombok)
implementation(libs.assertj)
implementation(project)
implementation(libs.picocli.core)
}
targets {
all {
testTask.configure {
systemProperty("symly.runtime.classpath", sourceSets.main.get().runtimeClasspath.asPath)
systemProperty("symly.testing.opaque-testing", properties["opaqueTesting"].toString())
shouldRunAfter(test)
}
}
}
}
tasks.check.get().dependsOn(integrationTest)
}
}
dependencies {
configurations["errorprone"](libs.errorprone)
compileOnly(libs.lombok)
annotationProcessor(libs.lombok)
implementation(libs.picocli.core)
annotationProcessor(libs.picocli.codegen)
}
tasks.jacocoTestReport {
dependsOn(testing.suites.named("test"), testing.suites.named("integrationTest"))
additionalSourceDirs.from(files(sourceSets.main.get().allSource.srcDirs))
sourceDirectories.from(files(sourceSets.main.get().allSource.srcDirs))
classDirectories.from(files(sourceSets.main.get().output))
executionData.from(
files(
"${buildDir}/jacoco/test.exec",
"${buildDir}/jacoco/integrationTest.exec",
)
)
reports {
html.outputLocation.set(layout.buildDirectory.dir("reports/jacoco/all"))
}
}
tasks.check.get().dependsOn(tasks.jacocoTestReport.get())
val generateManualStructure = tasks.register<JavaExec>("generateManualStructure") {
classpath(sourceSets.main.get().runtimeClasspath, configurations.annotationProcessor)
mainClass.set("picocli.codegen.docgen.manpage.ManPageGenerator")
args(
"org.${project.name}.cli.MainCommand",
"--factory=org.${project.name}.cli.BeanFactory",
"--outdir=${buildDir}/docs/manpage/adoc"
)
outputs.dir("${buildDir}/docs/manpage/adoc")
}
fun generateManual(output: String, backend: String): TaskProvider<org.asciidoctor.gradle.jvm.AsciidoctorTask> {
return tasks.register<org.asciidoctor.gradle.jvm.AsciidoctorTask>("generate${output.capitalize()}Manual") {
inputs.files(generateManualStructure)
sourceDir(file("${buildDir}/docs/manpage/adoc"))
setOutputDir(file("${buildDir}/docs/manpage/${output}"))
attributes(mapOf("reproducible" to true))
outputOptions {
backends(backend)
}
}
}
val generateManpageManual = generateManual("manpage", "manpage")
val generateHtmlManual = generateManual("html", "html5")
val compressManpageManual = tasks.register<Exec>("compressManpageManual") {
inputs.files(generateManpageManual)
outputs.dir("${buildDir}/docs/manpage/gz")
workingDir("${buildDir}/docs/manpage")
commandLine("/bin/sh", "-c", "rm -rf gz && cp -R manpage gz && gzip -n -9 gz/*")
}
val generateShellCompletions = tasks.register<JavaExec>("generateShellCompletions") {
classpath(sourceSets.main.get().runtimeClasspath)
mainClass.set("picocli.AutoComplete")
args(
"org.${project.name}.cli.MainCommand",
"--factory=org.${project.name}.cli.BeanFactory",
"--completionScript=${buildDir}/shell/completions/${project.name}",
"--force"
)
outputs.file("${buildDir}/shell/completions/${project.name}")
}
distributions {
main {
contents {
from("LICENSE")
from(generateManpageManual) {
into("doc/manpage")
}
from(generateHtmlManual) {
into("doc/html")
}
}
}
}
val prepareHomebrewBottle = tasks.register<Sync>("prepareHomebrewBottle") {
inputs.files(tasks.installDist, compressManpageManual)
val standardDistPath = tasks.installDist.get().outputs.files.singleFile.toPath()
from("LICENSE")
from("src/packaging/homebrew")
from(standardDistPath.resolve("bin/symly")) {
into("libexec/bin")
}
from(standardDistPath.resolve("lib")) {
into("libexec/lib")
}
from(compressManpageManual) {
into("share/man/man1")
}
from(generateHtmlManual) {
into("share/doc/${project.name}")
}
into("${buildDir}/distributions-preparation/homebrew")
}
val buildHomebrewBottle = tasks.register<Zip>("buildHomebrewBottle") {
from(prepareHomebrewBottle)
destinationDirectory.set(file("${buildDir}/distributions/"))
archiveFileName.set("${project.name}-${project.version}-homebrew-bottle.zip")
}
tasks.assemble.get().dependsOn(buildHomebrewBottle)
ospackage {
packageName = "symly"
packageDescription = "Manages symbolic links."
url = "https://github.com/loicrouchon/symly"
release = "1"
os = org.redline_rpm.header.Os.LINUX
user = "root"
license = "ASL 2.0"
from("LICENSE", closureOf<CopySpec> {
into("usr/share/doc/${project.name}")
rename("LICENSE", "copyright")
fileType = org.redline_rpm.payload.Directive.LICENSE
})
from("src/packaging/linux")
from("${buildDir}/install/${project.name}/bin/symly", closureOf<CopySpec> {
into("usr/share/${project.name}/bin")
})
from("${buildDir}/install/${project.name}/lib", closureOf<CopySpec> {
into("usr/share/${project.name}/lib")
})
from(compressManpageManual, closureOf<CopySpec> {
into("usr/man/man1")
fileType = org.redline_rpm.payload.Directive.DOC
})
// requires https ://github.com/remkop/picocli/issues/1346
// from(generateShellCompletions, closureOf<CopySpec> {
// into "/usr/share/bash-completion/completions"
// })
}
val buildDebPackage = tasks.register<com.netflix.gradle.plugins.deb.Deb>("buildDebPackage") {
dependsOn(tasks.installDist)
shouldRunAfter(tasks.named("integrationTest"))
maintainer = "Loic Rouchon"
license = "ASL 2.0"
requires("openjdk-17-jre-headless", "").or("java17-runtime-headless", null)
}
val buildRpmPackage = tasks.register<com.netflix.gradle.plugins.rpm.Rpm>("buildRpmPackage") {
dependsOn(tasks.installDist)
shouldRunAfter(tasks.named("integrationTest"))
packager = "Loïc Rouchon"
requires("java-latest-openjdk-headless", "")
addParentDirs = false
}
tasks.assemble.get().dependsOn(buildDebPackage, buildRpmPackage)