[Customization guide] How to make ← and → in menu mean to leave the completion mode and edit the command line?

[ImpleLee]

What do you want?

Add an customization guide in the README to describe how to make ← and → in menu mean editing the current command line.

Why do you want this?

I think it is straightforward to make ← and → mean editing instead of menu selection.

Who else would benefit from this?

Others that think ← and → is more suited as editing instead of menu selection.
This issue only wants to add an entry in the README, so this does not change current behavior.

How should it work?

I actually don't know. That is part of the reason that I want to make a feature request.

Given the following situation:

• I am in the completion menu.

When I perform the following steps:

1. I select some completion by ↑ and ↓.
2. Then I hit ← or →.

Then I expect the following to happen:

• I can edit the current command line (the completion I accepted).

[marlonrichert]

bindkey -M menuselect '<escape code for ←>' .backward-char
bindkey -M menuselect '<escape code for →>'  .forward-char

Documented in

• Zsh Modules > Menu selection
• Zsh Line Editor > Movement

[julien-blanchon]

What are the escapes right key, this don't work

bindkey -M menuselect '\e[D' backward-char
bindkey -M menuselect '\e[C' forward-char

[julien-blanchon]

Also

bindkey -M menuselect '^[[D' backward-char
bindkey -M menuselect '^[[C' forward-char

Don't work

[JerryZhongJ]

For me it doesn't work either. I added these to the end of .zshrc:

bindkey -M menuselect '^[[D' .backward-char
bindkey -M menuselect '^[[C' .forward-char

[amomchilov]

Oh boy, it took me like an hour to figure this out, but this fails when cusor keys mode ("DECCKM") is enabled. The sequnces are ^[OD and ^[OC instead.

That's what the prefix=( '\e'{\[,O} ) is for in the script from the README.md. It gets expanded out to call bindkey for both ^[[ and ^[O.

[amomchilov]

I'll add, I also figured out some more combinations:

Keyboard shortcut	Characters sent	Effect
Option ⌥ + ←	^[b	move left by a word
Option ⌥ + →	^[f	move right by a word
Command ⌘ + ←	^A	move to the start of the line
Command ⌘ + →	^E	move to the end of the line

bindkey -M menuselect "^[OD"   .backward-char # ←
bindkey -M menuselect "^[OC"    .forward-char # →
bindkey -M menuselect "^[b"    .backward-word # ⌥ + ←
bindkey -M menuselect "^[f"     .forward-word # ⌥ + →
bindkey -M menuselect "^A" .beginning-of-line # ⌘ + ←
bindkey -M menuselect "^E"       .end-of-line # ⌘ + →

The 4th and 6th ones are kind of redundant, because your insertion points already starts out on the end of the word/line. I just added it for completeness.

[JerryZhongJ]

I borrowed the idea from README.md, and this one work for me:

() {
   local -a prefix=( '\e'{\[,O} )
   local -a left=( ${^prefix}D ) right=( ${^prefix}C )
   local key=
   for key in $left[@]; do
      bindkey -M menuselect "$key" .backward-char
   done
   for key in $right[@]; do
      bindkey -M menuselect "$key" .forward-char
   done
}

[ImpleLee]

I personally use the following snippet and it works fine.

bindkey -M menuselect "$terminfo[kcub1]" .backward-char
bindkey -M menuselect "$terminfo[kcuf1]" .forward-char