signalfx-java-tracing.gradle

// Modified by SignalFx
plugins {
  id 'io.franzbecker.gradle-lombok' version '1.14' // Last to support Java 7

  id 'com.jfrog.artifactory' version '4.8.1'
  id 'com.jfrog.bintray' version '1.8.4'
  id 'org.unbroken-dome.test-sets' version '2.2.1'
  id 'com.github.ben-manes.versions' version '0.27.0'

  // Not applying google java format by default because it gets confused by stray java build
  // files in 'workspace' build directory in CI
  id 'com.github.sherter.google-java-format' version '0.8' apply false
  id 'com.dorongold.task-tree' version '1.5'
  id 'pl.allegro.tech.build.axion-release' version '1.10.3'
}

def isCI = System.getenv("CI") != null

scmVersion {
  tag {
    prefix = 'v'
    versionSeparator = ''
  }

  versionIncrementer 'incrementMinor'

  checks {
    uncommittedChanges = false
    aheadOfRemote = true
    snapshotDependencies = false
  }
}

allprojects {
  group = 'com.signalfx.public'
  // Don't forget to update TRACING_VERSION_VALUE in dd-trace-api/src/main/java/datadog/trace/api/Config.java
  version = '0.48.0-sfx11'

  if (isCI) {
    buildDir = "${rootDir}/workspace/${projectDir.path.replace(rootDir.path, '')}/build/"
  }

  apply from: "${rootDir}/gradle/dependencies.gradle"
  apply from: "${rootDir}/gradle/util.gradle"
}

repositories {
  mavenLocal()
  jcenter()
  mavenCentral()
}

description = 'signalfx-trace-java'

tasks.register("latestDepTest")

// Applied here to allow publishing of artifactory build info
apply from: "${rootDir}/gradle/publish.gradle"

wrapper {
  distributionType = Wrapper.DistributionType.ALL
}

allprojects {
  tasks.withType(JavaForkOptions).configureEach {
    maxHeapSize = System.properties["datadog.forkedMaxHeapSize"]
    minHeapSize = System.properties["datadog.forkedMinHeapSize"]
    jvmArgs "-XX:ErrorFile=/tmp/hs_err_pid%p.log"
  }
}