How can I install an update and restart an application at any time?

[ivan-diachenko-td]

Hello team,

Disclaimer: I don't use Sparkle UI, I override SPUUserDriver, SPUUpdaterDelegate and use my implementations when creating SPUUpdater.

I am trying to implement an update installation and restart at any time. I want to be able to check for an update, download it if it exists but dismiss the installation (AFAIK it can be done in showReadyToInstallAndRelaunch.reply(SPUUserUpdateChoiceDismiss)) so as to release the session and be able to do checks for updates later. But now I stumbled with how to install an update and restart the applications. I want to be able to implement a similar to Chrome's behavior with its "Relaunch to update" button:

If I just restart my app there are no guarantees that I will launch the same version and there would not be any issue since the restart process knows nothing about Sparkle updating the application.

Please, let me know if it is possible.

[zorgiepoo]

I think you can just not release the update UI session (not call showReadyToInstallAndRelaunch.reply(SPUUserUpdateChoiceDismiss)). If the user clicks the relaunch to update button you can call that handler to install/relaunch the app. You can still have the user check for updates later in this state which will invoke showUpdateInFocus.

[zorgiepoo]

I want to be able to check for an update, download it if it exists...

The right way to do this by the way is have Sparkle opt into automatic downloading of updates rather than using the user driver. I am not sure how you're doing it currently. See also #2452 for further context. I updated the SPUUserDriver documentation recently to include details about user authorization cases.

edit: So if you opt into automatic downloads you also won't necessarily have an update UI session started, but there are other ways to get a Relaunch to update experience. Let's see what you're doing first..

[ivan-diachenko-td]

Hello @zorgiepoo

Thank you for your cooperation, I appreciate that.

My current Sparkle integration looks something like this:

@interface AppUpdaterDelegate : NSObject <SPUUserDriver, SPUUpdaterDelegate>

@property(nonatomic, copy) void (^updateReply)(SPUUserUpdateChoice);
@property(nonatomic, strong) SPUUpdater* updater;

// Other props
...
@end

@implementation AppUpdaterDelegate

- (void)showUpdatePermissionRequest:(SPUUpdatePermissionRequest*)request
                              reply:
                                  (void (^)(SUUpdatePermissionResponse*))reply {
  SUUpdatePermissionResponse* response = [[SUUpdatePermissionResponse alloc]
      // We don't want Sparkle to automatically check for updates.
      initWithAutomaticUpdateChecks:false
                  sendSystemProfile:true];
  reply(response);
}

- (void)showUpdateFoundWithAppcastItem:(SUAppcastItem*)appcastItem
                                 state:(SPUUserUpdateState*)state
                                 reply:(void (^)(SPUUserUpdateChoice))reply {
  LOG(INFO) << "AppUpdaterDelegate::showUpdateFoundWithAppcastItem";
  NSString* newVersion = appcastItem.displayVersionString;
  if ([[self versionManager] isInstalledVersionSameOrGreaterThan:newVersion]) {
    // Since we don't relaunch the application in showReadyToInstallAndRelaunch,
    // Sparkle still thinks that the new version is not already downloaded and extracted. We should
    // store the installed version and in the case so called "new" update
    // is found, dismiss it.
    reply(SPUUserUpdateChoiceDismiss);
    notifyUpdateNotFound();
    return;
  }
  [[self versionManager] setLatestVersion:newVersion];
  // updateReply is called later in dismiss or install methods.
  self.updateReply = reply;
  notifyUpdateFound(appcastItem);
}

- (void)showUpdateNotFoundWithError:(NSError*)error
                    acknowledgement:(void (^)(void))acknowledgement {
  notifyUpdateNotFound();
  acknowledgement();
}

- (void)showReadyToInstallAndRelaunch:(void (^)(SPUUserUpdateChoice))reply {
  [[self versionManager] setInstalledVersionToLatest];
  reply(SPUUserUpdateChoiceDismiss);
  notifyUpdateDownloadedAndExtracted();
}

- (void)showDownloadDidReceiveDataOfLength:(uint64_t)length {
  notifyDownloadProgressChanged(length);
}

- (void)showExtractionReceivedProgress:(double)progress {
   notifyExtractionProgressChanged(progress);
}

- (instancetype)init {
  self = [super init];
  if (self) {
    NSBundle* hostBundle = [NSBundle mainBundle];
    SPUUpdater* updater = [[SPUUpdater alloc] initWithHostBundle:hostBundle
                                               applicationBundle:hostBundle
                                                      userDriver:self
                                                        delegate:self];
    _updater = updater;
    _progressManager = [[ProgressManager alloc] init];
    _versionManager = [[VersionManager alloc] init];
  }
  return self;
}

+ (instancetype)sharedInstance {
  static AppUpdaterDelegate* sharedInstance = nil;
  static dispatch_once_t onceToken;
  dispatch_once(&onceToken, ^{
    sharedInstance = [[self alloc] init];
    NSError* error = nil;
    sharedInstance.isSupported = YES;
    [sharedInstance.updater startUpdater:&error];
    if (error) {
      sharedInstance.isSupported = NO;
      LOG(ERROR) << "Failed to initialize Sparkle updater: "
                 << [[error localizedDescription] UTF8String];
    }
  });
  return sharedInstance;
}

- (BOOL)canCheckForUpdates {
  return [[self updater] canCheckForUpdates] &&
         ![[self updater] sessionInProgress];
}

- (void)checkForUpdates:(NSString*)appCastUrl {
  _appCastUrl = [appCastUrl copy];
  [[self updater] checkForUpdates];
}

// This can be invoked by the user after they are notified.
// After the invocation, the update is downloaded and extracted
- (void)install {
  if ([self updateReply] != nil) {
    [self updateReply](SPUUserUpdateChoiceInstall);
  }
  _updateReply = nil;
}

// This can be invoked by the user after they are notified.
- (void)dismiss {
  if ([self updateReply] != nil) {
    [self updateReply](SPUUserUpdateChoiceDismiss);
  }
  _updateReply = nil;
}

- (NSString*)feedURLStringForUpdater:(SPUUpdater*)updater {
  return [self appCastUrl];
}

- (BOOL)updaterShouldPromptForPermissionToCheckForUpdates:(SPUUpdater*)updater {
  // We don't want to show a prompt dialog that asks to check for updates
  // automatically. This is Sparkle's logic.
  return NO;
}

- (void)updater:(SPUUpdater*)updater
    didFinishUpdateCycleForUpdateCheck:(SPUUpdateCheck)updateCheck
                                 error:(nullable NSError*)error {
  if (error) {
    notifyErrorOccurred(error);
  }  
}

// Other SPUUserDriver and SPUUpdaterDelegate methods

@end

Then when I want to check for an update I do smth like this:

  AppUpdaterDelegate* delegate = [AppUpdaterDelegate sharedInstance];
  if ([delegate canCheckForUpdates]) {
    [delegate checkForUpdates:[NSString stringWithUTF8String:appCastUrl.c_str()]];
  }

Overall, I want to be able to check for an update, get notified when the update is found or not, download and extract it, and then be able to install the update and relaunch the app at any time.

[zorgiepoo]

Your checkForUpdates check is good if the user initiated the update check (via a button or menu item or so on). Otherwise background initiated checks should use checkForUpdatesInBackground.

If you just set SUEnableAutomaticChecks to NO you won't get update permission prompts or automatic checks for updates.

I recommend setting the feed URL in the Info.plist via SUFeedURL.

-showUpdateFoundWithAppcastItem:state:reply: can be entered when the update is already been downloaded or is already staged to be ready to be installed. You are ignoring the state and misunderstanding how the method works completely. Likewise, all the usages of your versionManager are unnecessary and can be removed.

So my first post was suggesting this: you can choose to not make a reply in showReadyToInstallAndRelaunch:. Hold onto the reply block until you want to later restart the application at 'any time'. Feel free to hide other UI though. If you want the user to be able to check for updates again while the user driver session is active, you can not override canCheckForUpdates the way you are doing, and use -showUpdateInFocus (checkForUpdates calls showUpdateInFocus when a UI session is active).

The important bit I mentioned in my second reply: I am assuming you are not automatically downloading/extracting the update on the user's behalf without notifying the user. In other words, you should not be hiding UI when showing the update to the user and when the update starts to download. Otherwise things may break when some users need to be requested authorization before extraction and may see an unexpected surprise.