Enable unittest.suite to accept partial calls of rules

This permits using `unittest.suite` with test rules that have nondefault
attributes, while retaining compatibility with current usage.

For instance, this permits setting a `timeout` on each test in a
`unittest.suite`.  Previously, all tests in a `unittest.suite` would
have the default timeout, with no good way to alter this.  This
made it hard to eliminate all the warnings produced from using the
`--test_verbose_timeout_warnings` bazel option.

While timeouts were the motivation, the solution here is not specific
to timeouts. It will permit arbitrary additional arguments to the test
rules in a `unittest.suite`.

Fixes #98

lib/BUILD

@@ -71,6 +71,7 @@ bzl_library(
     srcs = ["unittest.bzl"],
     deps = [
         ":new_sets",
+        ":partial",
         ":sets",
         ":types",
     ],

lib/types.bzl

@@ -138,6 +138,20 @@ def _is_set(v):
     """
     return type(v) == _a_struct_type and hasattr(v, "_values") and _is_dict(v._values)
 
+def _is_partial(v):
+    """Returns True if v is a set created by partial.make().
+
+    Args:
+      v: The value whose type should be checked.
+
+    Returns:
+      True if v was created by partial.make(), False otherwise.
+    """
+    return type(v) == _a_struct_type \
+        and hasattr(v, "function") and _is_function(v.function) \
+        and hasattr(v, "args") and _is_tuple(v.args) \
+        and hasattr(v, "kwargs") and _is_dict(v.kwargs)
+
 types = struct(
     is_list = _is_list,
     is_string = _is_string,
@@ -149,4 +163,5 @@ types = struct(
     is_function = _is_function,
     is_depset = _is_depset,
     is_set = _is_set,
+    is_partial = _is_partial,
 )

lib/unittest.bzl

@@ -20,6 +20,7 @@ assertions used to within tests.
 """
 
 load(":new_sets.bzl", new_sets = "sets")
+load(":partial.bzl", "partial")
 load(":types.bzl", "types")
 
 # The following function should only be called from WORKSPACE files and workspace macros.
@@ -229,18 +230,18 @@ def _suite(name, *test_rules):
     writing a macro in your `.bzl` file to instantiate all targets, and calling
     that macro from your BUILD file so you only have to load one symbol.
 
-    For the case where your unit tests do not take any (non-default) attributes --
-    i.e., if your unit tests do not test rules -- you can use this function to
-    create the targets and wrap them in a single test_suite target. In your
-    `.bzl` file, write:
+    You can use this function to create the targets and wrap them in a single
+    test_suite target. If a test rule requires no arguments, you can simply list
+    it as an argument. If you wish to supply attributes explicitly, you can do so
+    using `partial.make()`. For instance, in your `.bzl` file, you could write:
 
     ```
     def your_test_suite():
       unittest.suite(
           "your_test_suite",
           your_test,
           your_other_test,
-          yet_another_test,
+          partial.make(yet_another_test, timeout = "short"),
       )
     ```
 
@@ -266,7 +267,10 @@ def _suite(name, *test_rules):
     test_names = []
     for index, test_rule in enumerate(test_rules):
         test_name = "%s_test_%d" % (name, index)
-        test_rule(name = test_name)
+        if types.is_partial(test_rule):
+            partial.call(test_rule, name = test_name)
+        else:
+            test_rule(name = test_name)
         test_names.append(test_name)
 
     native.test_suite(

tests/types_tests.bzl

@@ -13,6 +13,7 @@
 # limitations under the License.
 """Unit tests for types.bzl."""
 
+load("//lib:partial.bzl", "partial")
 load("//lib:types.bzl", "types")
 load("//lib:unittest.bzl", "asserts", "unittest")
 load("//lib:new_sets.bzl", "sets")
@@ -231,6 +232,22 @@ def _is_set_test(ctx):
 
 is_set_test = unittest.make(_is_set_test)
 
+def _is_partial_test(ctx):
+    """Unit test for types.is_partial."""
+    env = unittest.begin(ctx)
+
+    asserts.true(env, types.is_partial(partial.make(is_set_test)))
+    asserts.true(env, types.is_partial(partial.make(is_set_test, timeout = "short")))
+    asserts.true(env, types.is_partial(partial.make(is_set_test, timeout = "short", tags = ["foo"])))
+    asserts.false(env, types.is_partial(None))
+    asserts.false(env, types.is_partial({}))
+    asserts.false(env, types.is_partial(struct(foo = 1)))
+    asserts.false(env, types.is_partial(struct(function = "not really function")))
+
+    return unittest.end(env)
+
+is_partial_test = unittest.make(_is_partial_test)
+
 def types_test_suite():
     """Creates the test targets and test suite for types.bzl tests."""
     unittest.suite(
@@ -245,4 +262,5 @@ def types_test_suite():
         is_function_test,
         is_depset_test,
         is_set_test,
+        is_partial_test,
     )

tests/unittest_test.sh

@@ -73,6 +73,7 @@ exports_files(["*.bzl"])
 EOF
   ln -sf "$(rlocation bazel_skylib/lib/dicts.bzl)" lib/dicts.bzl
   ln -sf "$(rlocation bazel_skylib/lib/new_sets.bzl)" lib/new_sets.bzl
+  ln -sf "$(rlocation bazel_skylib/lib/partial.bzl)" lib/partial.bzl
   ln -sf "$(rlocation bazel_skylib/lib/sets.bzl)" lib/sets.bzl
   ln -sf "$(rlocation bazel_skylib/lib/types.bzl)" lib/types.bzl
   ln -sf "$(rlocation bazel_skylib/lib/unittest.bzl)" lib/unittest.bzl

tests/unittest_tests.bzl

@@ -14,6 +14,7 @@
 
 """Unit tests for unittest.bzl."""
 
+load("//lib:partial.bzl", "partial")
 load("//lib:unittest.bzl", "analysistest", "asserts", "unittest")
 
 ###################################
@@ -42,6 +43,19 @@ def _basic_passing_test(ctx):
 
 basic_passing_test = unittest.make(_basic_passing_test)
 
+#################################################
+####### basic_passing_short_timeout_test ########
+#################################################
+def _basic_passing_short_timeout_test(ctx):
+    """Unit tests for a basic library verification test."""
+    env = unittest.begin(ctx)
+
+    asserts.equals(env, ctx.attr.timeout, "short")
+
+    return unittest.end(env)
+
+basic_passing_short_timeout_test = unittest.make(_basic_passing_short_timeout_test)
+
 ###################################
 ####### change_setting_test #######
 ###################################
@@ -234,6 +248,7 @@ def unittest_passing_tests_suite():
     unittest.suite(
         "unittest_tests",
         basic_passing_test,
+        partial.make(basic_passing_short_timeout_test, timeout = "short"),
     )
 
     change_setting_test(