Regression: Unable to pass java.util.Properties object using Worker API in Gradle 5.6

[steffenyount]

Passing a java.util.Properties object in the Worker API fails in Gradle 5.6 but not in Gradle 5.5.1

E.g. a simple project defined with ~/tstProj/build.gradle:

import org.gradle.api.DefaultTask
import org.gradle.api.tasks.TaskAction
import org.gradle.workers.IsolationMode
import org.gradle.workers.WorkerExecutor

import javax.inject.Inject

task myTask(type: MyTask) {
    description 'My Task'
}

class MyTask extends DefaultTask {
    final WorkerExecutor workerExecutor

    @Inject
    MyTask(WorkerExecutor workerExecutor) {
        this.workerExecutor = workerExecutor
    }

    @TaskAction
    def run() {
        Properties myProps = new Properties()
        myProps.setProperty('key1', 'value1')
        myProps.setProperty('key2', 'value2')
        myProps.setProperty('key3', 'value3')

        workerExecutor.submit(MyRunner.class) { config ->
            config.isolationMode = IsolationMode.PROCESS

            config.params(myProps)
        }

        workerExecutor.await()
    }

    private static class MyRunner implements Runnable {
        Properties myProps

        @Inject
        MyRunner(Properties myProps) {
            this.myProps = myProps
        }

        @Override
        void run() {
            Properties myProps = this.myProps;
            myProps.store(System.out, null)
        }
    }
}

Expected Behavior

./gradlew myTask
...
> Task :myTask
Caching disabled for task ':myTask' because:
  Build cache is disabled
Task ':myTask' is not up-to-date because:
  Task has not declared any outputs despite executing actions.
#Tue Aug 20 16:00:22 PDT 2019
key3=value3
key2=value2
key1=value1
:myTask (Thread[Execution worker for ':' Thread 2,5,main]) completed. Took 1.209 secs.

BUILD SUCCESSFUL in 1s
1 actionable task: 1 executed

Current Behavior

./gradlew myTask
...
> Task :myTask FAILED
Caching disabled for task ':myTask' because:
  Build cache is disabled
Task ':myTask' is not up-to-date because:
  Task has not declared any outputs despite executing actions.
:myTask (Thread[Execution worker for ':',5,main]) completed. Took 0.796 secs.

FAILURE: Build failed with an exception.

* Where:
Build file '/Users/steffenyount/dev/2/tstProj/build.gradle' line: 33

* What went wrong:
Execution failed for task ':myTask'.
> There was a failure while executing work items
   > A failure occurred while executing MyTask$MyRunner
      > Could not create an instance of type MyTask$MyRunner.
         > Unable to determine constructor argument #1: value {key3=value3, key2=value2, key1=value1} not assignable to class java.util.Properties

* Try:
Run with --stacktrace option to get the stack trace. Run with --debug option to get more log output. Run with --scan to get full insights.

* Get more help at https://help.gradle.org

BUILD FAILED in 2s
1 actionable task: 1 executed

Context

I'm attempting to upgrade our large multi-project build from 5.4.1 -> 5.6 and one of our custom build tasks has been using the Worker API like I've shown in the example code above.

The upgrade to 5.6 breaks this build task.

Steps to Reproduce

See example above.

Note: if I rewire my example to pass a LinkedHashMap<Object, Object> object to the MyRunner class instead of the Properties object there is no failure.

Your Environment

OSX

[rgoldberg]

While the bug should be fixed, you might be able to work around it by using the new Worker API introduced in 5.6 (the new Worker API might, however, also have the same bug).

WorkerExecutor#submit has been deprecated, so you should probably move to the new API, anyway.

See https://docs.gradle.org/5.6/userguide/custom_tasks.html#using-the-worker-api

[steffenyount]

@rgoldberg - I tried that with the following code and I got it to work, but I'm seeing a deprecation warning about not using ObjectFactory.mapProperty() which I don't think I have any control over:

import org.gradle.api.DefaultTask
import org.gradle.api.tasks.TaskAction
import org.gradle.workers.IsolationMode
import org.gradle.workers.WorkAction
import org.gradle.workers.WorkParameters
import org.gradle.workers.WorkQueue
import org.gradle.workers.WorkerExecutor

import javax.inject.Inject

task myTask(type: MyTask) {
    description 'My Task'
}

class MyTask extends DefaultTask {
    final WorkerExecutor workerExecutor

    @Inject
    MyTask(WorkerExecutor workerExecutor) {
        this.workerExecutor = workerExecutor
    }

    @TaskAction
    def run() {
        Properties myProps = new Properties()
        myProps.setProperty('key1', 'value1')
        myProps.setProperty('key2', 'value2')
        myProps.setProperty('key3', 'value3')

        final WorkQueue workQueue = workerExecutor.processIsolation();

        workQueue.submit(MyRunner.class, { MyParameters params ->
            params.myProps = myProps
        })
    }

    static interface MyParameters extends WorkParameters {
        Property<Properties> getMyProps();
    }

    static abstract class MyRunner implements WorkAction<MyParameters> {
        @Override
        public void execute() {
            Properties myProps = parameters.myProps.get()
            myProps.store(System.out, null)
        }
    }
}

result:

./gradlew myTask
...
> Task :myTask
Caching disabled for task ':myTask' because:
  Build cache is disabled
Task ':myTask' is not up-to-date because:
  Task has not declared any outputs despite executing actions.
Using method ObjectFactory.property() method to create a property of type Map<K, V> has been deprecated. This will fail with an error in Gradle 6.0. Please use the ObjectFactory.mapProperty() method instead.
	at MyTask$_run_closure1.doCall(/Users/steffenyount/dev/2/tstProj/build.gradle:33)
	(Run with --stacktrace to get the full stack trace of this deprecation warning.)
#Wed Aug 21 15:17:48 PDT 2019
key3=value3
key2=value2
key1=value1
:myTask (Thread[Execution worker for ':',5,main]) completed. Took 1.49 secs.

BUILD SUCCESSFUL in 2s
1 actionable task: 1 executed

Note: My previous post was retracted after I realized a typo in my previous example implementation was causing the build failure.

[rgoldberg]

@steffenyount; Glad the new API is working. Can you file a new bug for the deprecation warning if one hasn’t been filed already? I think 5.6.1 is the next scheduled release, to be followed by 6.0, so this will cause errors soon. Makes sense to get the fix in 5.6.1 if they can squeeze it in.

[steffenyount]

@rgoldberg - I've filed a new bug for that here: #10341

[rgoldberg]

@steffenyount: Cool. Hopefully the deprecated code usage will be fixed before errors occur.

[steffenyount]

@rgoldberg - To better simulate our actual build scripts, I tried a different variant of this new Worker API implementation where I've defined the MyTask class in a java source file instead of in a groovy file, and I am seeing failures again.

E.g. a simple project defined across two files
~/buildSrc/src/main/java/MyTask.java:

import org.gradle.api.provider.Property;
import org.gradle.api.DefaultTask;
import org.gradle.api.tasks.TaskAction;
import org.gradle.workers.IsolationMode;
import org.gradle.workers.WorkAction;
import org.gradle.workers.WorkParameters;
import org.gradle.workers.WorkQueue;
import org.gradle.workers.WorkerExecutor;

import java.io.IOException;
import java.util.Properties;
import javax.inject.Inject;

public class MyTask extends DefaultTask {
    final WorkerExecutor workerExecutor;

    @Inject
    public MyTask(WorkerExecutor workerExecutor) {
        this.workerExecutor = workerExecutor;
    }

    @TaskAction
    public void run() {
        Properties myProps = new Properties();
        myProps.setProperty("key1", "value1");
        myProps.setProperty("key2", "value2");
        myProps.setProperty("key3", "value3");

        final WorkQueue workQueue = workerExecutor.processIsolation();

        workQueue.submit(MyRunner.class, (MyParameters params) -> {
            params.getMyProps().set(myProps);
        });
    }

    interface MyParameters extends WorkParameters {
        Property<Properties> getMyProps();
    }

   public static abstract class MyRunner implements WorkAction<MyParameters> {
        @Override
        public void execute() {
            final MyParameters params = getParameters();

            final Properties myProps = params.getMyProps().get();

            try {
                myProps.store(System.out, null);
            } catch (IOException e) {
                // do nothing
            }
        }
    }
}

~/tstProj/build.gradle:

import MyTask

task myTask(type: MyTask) {
    description 'My Task'
}

result:

./gradlew myTask
...
> Task :myTask FAILED
Caching disabled for task ':myTask' because:
  Build cache is disabled
Task ':myTask' is not up-to-date because:
  Task has not declared any outputs despite executing actions.
Using method ObjectFactory.property() method to create a property of type Map<K, V> has been deprecated. This will fail with an error in Gradle 6.0. Please use the ObjectFactory.mapProperty() method instead.
:myTask (Thread[Execution worker for ':',5,main]) completed. Took 0.013 secs.

FAILURE: Build failed with an exception.

* What went wrong:
Execution failed for task ':myTask'.
> A failure occurred while executing MyTask$MyRunner
   > java.util.LinkedHashMap cannot be cast to java.util.Properties

* Try:
Run with --stacktrace option to get the stack trace. Run with --debug option to get more log output. Run with --scan to get full insights.

* Get more help at https://help.gradle.org

BUILD FAILED in 737ms
1 actionable task: 1 executed

Note: if I rewire this example to set a LinkedHashMap object and return a Property<Map<Object, Object>> from the MyParameters interface there is no failure, though the aforementioned warning appears:

Using method ObjectFactory.property() method to create a property of type Map<K, V> has been deprecated. This will fail with an error in Gradle 6.0. Please use the ObjectFactory.mapProperty() method instead.

Do you need 2 more bugs filed for these 2 issues: the failure and the warning?

[rgoldberg]

@steffenyount: I don't work on the Gradle project, so I don't know for sure if the Gradle team would want 2 additional bugs filed, but I highly doubt it. These 2 Java symptoms are probably all caused by the same bugs as your Groovy + old Worker API symptoms & your Groovy + new Worker API symptoms.

I imagine that somehow Groovy Magic® can auto-convert between LinkedHashMap & Properties in the code for the new API, but that it can't convert in the code for the old API. I also imagine that Java will fail for both APIs since it doesn't perform magic conversions at all.

[steffenyount]

While these bugs are likely all related they do manifest slightly differently, and so probably need separate tests to validate that they've been fixed.

I've gone ahead and created a ticket for the warning that appears when I'm passing a Map object through the new Worker API in a Java implementation: #10343

If the folks who do work on the Gradle project want to close it as a duplicate that's fine.

Update: the warning from passing a Map object through the new Worker API in a Java implementation was avoidable by using a MapProperty<> instead of a Property<Map<>> and I have closed that ticket.

[ghale]

Thanks for the report @steffenyount. The fix for this will be in 5.6.1. You can try this out now with the latest release nightly (https://gradle.org/release-nightly/).

[steffenyount]

verified using distributionUrl=https\://services.gradle.org/distributions-snapshots/gradle-5.6.1-20190823130927+0000-bin.zip

The code originally provided above now results in the following successful build as expected:

./gradlew myTask
...
> Task :myTask
Caching disabled for task ':myTask' because:
  Build cache is disabled
Task ':myTask' is not up-to-date because:
  Task has not declared any outputs despite executing actions.
#Fri Aug 23 09:56:42 PDT 2019
key3=value3
key2=value2
key1=value1
:myTask (Thread[Execution worker for ':',5,main]) completed. Took 1.001 secs.

BUILD SUCCESSFUL in 1s
1 actionable task: 1 executed

Thank you